Not logged inClonkspot Forum
Forum Home Help Search Register Login
Up Topic Deutsch / Hilfestellung / [Gelöst] Gegenstand radioaktiv machen
- - By Serpens66 (More than 200 posts.) Date 16.09.2014 19:58 Edited 16.09.2014 20:03
Im StarEmpire Pack gibt es ja einen nuklearen Sprengsatz, der nach Explosion strahlt und je näher Clonks dem Explosionsort kommen, desto mehr schaden bekommen sie.

Hier der Explosionsteil der NuklearBombe:
/* Explosion */

public Incineration:
  // Fragmente
  var i, obj;
  for (i = 1; i <= 10; i++)
  {
    obj = CreateObject(SFRX, Random(50)-25, Random(50)-25, GetOwner());
    ObjectCall(obj, "Settings", i, 25);
  }
  // Druckwelle & Strahlung
  obj = CreateObject(SWAV);
  ObjectCall(obj, "SetSize", 300,GetX(),GetY(), 400+Random(100), 700+Random(300));
  // Explosion
  CreateParticle("Blast", 0,0,0,0, 1500,RGB(0,255,0));
  Explode(160);
  return(1);

Es wird eine Druckwelle SWAV ausgelöst, welche dann widerum für die radioaktivität sorgt, ein teil aus dem SWAV Script:


public func SetSize(newsize, posX, posY, rad_effect, emp_effect)
{
  var obj;
  // Strahlung freisetzen
  if (rad_effect)
  {
    obj = CreateObject(SRAD,0,25,GetOwner());
    obj->SetRadTime(rad_effect);
    SetPosition(posX, posY, obj);
  }

Das "radioaktiv" Objekt SRAD befindet sich unter General/effects/Radiation. Das Skript sieht folgendermaßen aus:

/*-- Strahlung --*/

/#strict

local strength, Actnum;

/* Initialisierungs-Aufruf */

public func SetRadTime(time)
{
  // Timer einstellen, 1000fache Präzision
  strength = time * 1000;
  var obj;
  while (obj = FindObject(SRAD,-50,-50,100,100))
    MergeWith(obj);
  SetAction("Process");
  ChangeDir(SelectDir());
}

public func GetRadTime()
{
  return(strength);
}

/* Action-Call */

protected func Radiation()
{
  ReduceRadiation(994);
  var obj, damage;
  var str = strength/300;
  while (obj = FindObject(0,0,0,0,0, OCF_Alive(),0,0,NoContainer(),obj))
    if (!InLiquid(obj))
      if (!obj->~Radiation())
        if ((damage = (str-ObjectDistance(obj))/120) > 0)
          DoEnergy(-damage, obj);
  // Aktion wechseln
  var num = SelectDir();
  if (num == Actnum) return(1);
  if (Inside(Actnum-num, 1, 2)) SetPhase((Actnum-num)*2);
                           else SetPhase(0);
  ChangeDir(num);
}

public func ReduceRadiation(perc)
{
  // Strahlung abschwächen
  strength = strength/1000*perc;
  // löschen bei weniger als 50000
  if (strength < 50000) RemoveObject();
}

private func ChangeDir(dir)
{
  SetDir(dir);
  Actnum = dir;
}

private func SelectDir()
{
  if (strength < 75000)  return(0);
  if (strength < 110000) return(1);
  if (strength < 160000) return(2);
  if (strength < 240000) return(3);
  if (strength < 350000) return(4);
  if (strength < 520000) return(5);
  if (strength < 800000) return(6);
  return(7);
}

/* Strahlungsquellen zusammenfassen */

private func MergeWith(target)
{
  // Strahlungsstärke der anderen Quelle
  var otherstr = target->GetRadTime();
  if (!otherstr) return(0);
  var both = strength + otherstr;
  // neue Position einstellen
  SetPosition(GetX(target) + (GetX()-GetX(target)) * strength / both,
              GetY(target) + (GetY()-GetY(target)) * strength / both);
  strength = both;
  RemoveObject(target);
  return(1);
}


Ich habe nun ein neues Material erstellt, "Plutonium" (knallgrünes Erz), welches als Abfallprodukt im Atomkraftwerk entstehen soll, welches im SpaceLaunch Teil des SE-Packs zu finden ist.  Um diesen mächtigen nuklearen Sprengsatz dann herstellen zu können, soll Plutonium vonnöten sein, also auch zwingend ein Atomkraftwerk.  Das Plutonium selbst soll dabei aber "strahlen".  Es soll nur ein sehr kleiner Radius sein, also vllt eine Länge von 3 clonks nebeneinander ^^.  Auch soll es natürlich nicht sofort töten, wenn ein Clonk es einsammelt, aber schon merklich die Lebenspunkte reduzieren und dann vllt nach 20 sekunden töten.
Um dennoch mit dem Material arbeiten zu können, könnte man in der Rüstung oder dem Schildgenerator des Hazardpacks etwas einprogrammieren, wodurch die Strahlung deutlich weniger Schaden anrichtet (am besten auch die Strahlung der Nuklearexplosion).

Leider leider übersteigt das mal wieder meine programmierkenntnisse... wisst ihr wie ich das mit den vorhandenen Skripten gut umsetzen kann?
Parent - - By Zapper (More than 500 posts.) Date 16.09.2014 22:10 Edited 16.09.2014 22:12

>Leider leider übersteigt das mal wieder meine programmierkenntnisse... wisst ihr wie ich das mit den vorhandenen Skripten gut umsetzen kann?


Ich kann ja mal die ultra-Minimalversion für sowas geben:


func Initialize()
{
  // rufe die Effektfunktion in diesem Objekt alle fünf Frames auf
  AddEffect("Radiate", this, 1, 5, this);
}

func FxRadiateTimer(pTarget, iEffectNumber, iTime)
{
  var maximum_distance = 30;
  // suche nach Zielen und mache denen dann Schaden je nachdem wie weit sie weg sind
  for (var obj in FindObjects(Find_Distance(maximum_distance), Find_OCF(OCF_Alive)))
  {
    var distance = Distance(GetX(), GetY(), obj->GetX(), obj->GetY());
    var distance_factor = 100 - (100 \* distance / maximum_distance); // in Prozent!
    var damage = distance_factor * 50;
    DoEnergy(-damage, obj, true);
  }
}


Grafische Effekte musst du selbst basteln - zB per CastParticles :)
Parent - - By Serpens66 (More than 200 posts.) Date 16.09.2014 22:44
super vielen dank :) klappt einwandfrei :)
ja mal schauen, ob und was ich für grafische Effekte da noch machen kann...  vllt nehm ich auch einfach nur einen "aua" sound der Clonks.
Parent - - By Serpens66 (More than 200 posts.) Date 16.09.2014 22:59 Edited 16.09.2014 23:04
ach vllt doch noch für die Zukunft ein paar Fragen, wie deine Funktionen funktionieren:

wie kommst du auf:
AddEffect("Radiate", this, 1, 5, this); ?
sowas habe ich bisher noch in keinem Script gesehen. Ich hätte jetzt sowas erwartet wie
func Initialize()
{ FxRadiateTimer(pTarget, iEffectNumber, iTime) }

ach und wie wirken sich die Dinge in Klammern aus (sowohl das aus addeffect, als auch aus FxRadiateTimer)? Sind das automatisch Variablen, oder was ist das? Du verwendest "itime" sonst nirgends, also nehme ich an, dass das vordefintierte Wörter sind? Gibt es da eine Liste für?
Ich glaube den Rest verstehe ich =)

Deine Funktion wird ja alle 5 Frames aufgerufen. Wenn ich nun möchte, dass alle z.b 30 Frames dann der "aua" sound ertönt, wie muss das dann aussehen?
func Initialize()
{
AddEffect("Aua", this, 1, 30, this);
}

func FxAuaTimer(pTarget, iEffectNumber, iTime)
{
Sound ("Aua*");
}

so richtig?
(muss noch schauen, welches der richtige sound ist)
Parent - By Luchs (More than 1000 posts.) Date 16.09.2014 23:32
Die [Effekte-Dokumentation](http://crdocs.clonkspot.org/de/sdk/script/Effects.html) erklärt sehr wortreich, was da vor sich geht. Ganz unten ist eine Übersicht der Funktionen und Parameter.
Parent - - By Zapper (More than 500 posts.) Date 17.09.2014 10:25

>wie kommst du auf...


Zusätzlich zu dem Link von Luchs nochmal eine kleine Zusammenfassung:
In Clonk gibt es ein "Effekt"-System. "Effekte" sind Dinge, die du an Objekte ranhängen kannst und für die dann in bestimmten Situationen Funktionen aufgerufen werden. Alle Effektfunktionen heissen immer Fx + Effektname + Callbackname. Callbacks gibt es verschiedene: zB Fx\*Timer, der in bestimmten Zeitabständen aufgerufen wird. Oder Fx\*Damage, der aufgerufen wird wenn das Objekt Schaden nimmt. Oder Fx\*Stop wenn der Effekt gelöscht wird. Da gibt es natuerlich noch viel mehr.

Jeder dieser Callbacks hat bestimmte vordefinierte Parameter - das sind die Dinge in den Klammern. Der Fx\*Timer Callback bekommt zum Beispiel wie viel Zeit schon vergangen ist (iTime) und dafür bekommt der Fx\*Damage Callback, wie viel Schaden verursacht wurde.

Jeder Effektcallback bekommt immer das Ziel vom Effekt pTarget. Das habe ich bei dir nicht gebraucht, weil das Ziel vom Effekt gleichzeitig das Objekt ist, in dem die Funktionen stehen.
Du kannst aber auch Effekte an andere Objekte ranhängen.

zB könntest du in die Schleife oben, direkt nach DoEnergy sowas ranhängen:
AddEffect("Sparkle", obj, 1, 30, 0, GetID());

Und dir dann im Script weiter unten sowas definieren:

func FxSparkleTimer(pTarget, iEffectNumber, iTime)
{
  if (iTime > 36 * 10) return -1;
  pTarget->CastParticles("PxSpark", 30, 50, 0, 0, 10, 50, RGB(0, 100, 0), RGB(100, 255, 100));
}

Dann sprühen getroffene Clonks noch ein paar Sekunden lang Funken.

Bemerkungen:
- iTime zählt in Frames. Eine Sekunde hat etwa 36 Frames.
- Wenn die Fx\*Timer Funktion -1 zurückgibt, wird der Effekt entfernt
- Diesmal haben wir in AddEffect als Ort wo der Effekt definiert ist eine Definition GetID angegeben und kein Objekt. Der Unterschied ist etwas feiner und schwerer zu erklären - aber das ist keine schlechte Idee, wenn man den Effekt an ein anderes Objekt ranklatscht.

PS: Dein Aua-Effekt sieht so richtig aus, ja
Parent - - By Serpens66 (More than 200 posts.) Date 17.09.2014 12:56 Edited 17.09.2014 12:59
vielen dank für die Erklärung und auch die Funken  =)
da hab ich ja wieder was absolut geniales gelernt :)  wenn in dem Tempo immer wieder neue Möglichkeiten dazu kommen, wird mein "Projekt" ja nie fertig, weil immer wieder neues gemacht wird :D

Zu dem "aua" sound.  Wenn ich den AddEffect im Initialize schreibe, dann wird es ja dauerhaft für das Objekt abgespielt, so wie es sich bei dem Schaden verhält, den es macht. Also wäre das wohl nicht ganz so richtig.  Vllt wäre in dem Fall die von dir erwähnte Damage Funktion sinnvoller, sodass der Sound nur bei verussachtem Schaden biem Clonk abgespielt wird :)

AddEffect("Aua", obj, 1, 10, 0, GetID());

func FxAuaDamage(pTarget, iEffectNumber, iDmgEngy, iCause)
{
  if (iDamage > 10)
  Sound("Aua");
}

hmm.. ich bin mir fast sicher, das das so nicht funktioniert... es wird ja nirgends gesagt, dass es einen Clonk treffen soll... Demnach werden evlt auch andere Lebewesen (tiere) die durch den Schadensradius getroffen werden "aua" sagen?  Wobei vermutlich selbst das mit der jetzigen Funktion nicht funktioniert :D
vermutlich brauche ich hier auch eine Schleife, wie du es bei der Schadensverteilung gemacht hast...  aber warum eigentlich? Deine Funktion wird doch alle 5 Frames aufgerufen, also wieso braucht man da noch eine schelife?
Parent - - By Zapper (More than 500 posts.) Date 17.09.2014 13:20

>hmm.. ich bin mir fast sicher, das das so nicht funktioniert... es wird ja nirgends gesagt, dass es einen Clonk treffen soll... Demnach werden evlt auch andere Lebewesen (tiere) die durch den Schadensradius getroffen werden "aua" sagen?  Wobei vermutlich selbst das mit >der jetzigen Funktion nicht funktioniert :D


Moment! Fx\*Damage wird aufgerufen, wenn das Objekt Schaden nimmt, nicht wenn es ihn verteilt. Also müsste das dann in deinem Fall auf dem Clonk drauf sein.
Aber viel einfacher wäre es den Sound direkt da abzuspielen wo der Schaden verteilt wird. Z.B. sowas hier einfach unter die Zeile mit dem DoEnergy klatschen:
if (Random(10) == 0) Sound("Aua*");
Random(x) zieht eine Zufallszahl zwischen 0 und x-1. Also hier würde bei so jedem zehnten Mal der Sound abgespielt werden.

>vermutlich brauche ich hier auch eine Schleife, wie du es bei der Schadensverteilung gemacht hast...  aber warum eigentlich? Deine Funktion wird doch alle 5 Frames aufgerufen, also wieso braucht man da noch eine schelife?


Die Schleife macht den Schaden an jedes Lebewesen im Umkreis. Und dieses Schadensverteilen wird dann eben alle 5 Frames gemacht. Ohne Schleife könntest du immer nur einem Lebewesen auf einmal Schaden machen.
Parent - - By Serpens66 (More than 200 posts.) Date 17.09.2014 13:36 Edited 17.09.2014 15:35
Okay, soweit klappt alles =)  habe die Sparkles etwas reduziert "AddEffect("Sparkle", obj, 1, 1, 0, GetID());" und "if (iTime > 1 * 1) return -1;", damit die Funken sofort aufhören, sobald man außerhalb der Reichweite ist und nicht noch ca. 10 sekunden weiter sprühen.

Dennoch sollte man den Aua Sound wohl auf Clonks beschränken, da es doch etwas merkwürdig ist, wenn Fische und Co "Aua" rufen :D
Also muss ich das in einem appendto für clonks regeln? Und da dann einen Damage Effekt hinzufügen?

Wenn wir aber schon bei "Random" sind, es gibt 3 Sounds, Hurt1 bis Hurt3. Durch den Random Befehl könnte man dann ja z.b jedes 30te mal Sound 1 , sound 2 und sound 3 abspielen, super =)
Parent - - By Zapper (More than 500 posts.) Date 17.09.2014 20:05

>sofort aufhören


Wenn die Funken nur einmal kommen sollen, kannst du die Zeile mit den CastParticles natuerlich auch wieder in die Schleife übernehmen, die den Schaden macht, und pTarget mit obj tauschen.
Das mit dem Effekt war jetzt eher so das Beispiel wie du einen Effekt an ein anderes Objekt klatschen kannst :)

>Also muss ich das in einem appendto für clonks regeln? Und da dann einen Damage Effekt hinzufügen?


Oder du prüfst einfach ob dein obj ein Clonk ist. Ich glaube Clonks haben den Callback IsClonk().
Also zB in deine Schleife if (obj->~IsClonk()) Sound("Aua*");

>Wenn wir aber schon bei "Random" sind, es gibt 3 Sounds, Hurt1 bis Hurt3. Durch den Random Befehl könnte man dann ja z.b jedes 30te mal Sound 1 , sound 2 und sound 3 abspielen, super =)


Bei Sounds gibt es sogar noch den Trick mit dem Sternchen.
Wenn du die Sounds Hurt1.wav, Hurt2.wav und Hurt3.wav hast, kannst du einen zufällig davon mit Sound("Hurt*") abspielen.
Parent - - By Serpens66 (More than 200 posts.) Date 17.09.2014 20:43
ah danke, da kommt das sternchen also her ^^ :)

habe jetzt " if (!Random(5) & obj->~IsClonk()) Sound("Hurt*");"  genommen, damit der sound nur mit einer wahrscheinlichkeit von 1 zu 5 abgespielt wird und es klappt :)
zusätzlich leuchtet das Plutonium durch die Hazardlichteffekte nun grün, kann nicht verkauft oder aus dem Rand geworfen werden und wenn es gesprengt wird hinterlässt es einen kleinen radioaktiven Bereich, die Funktion dafür habe ich aus den Isotopen des StarEmpire Packs/General/Items entnommen :)

Damit ist es fertig, vielen vielen dank nochmal und auch für all die vielen anderen Fragen die du und die anderen beantwortet =)
Parent - - By Luchs (More than 1000 posts.) Date 17.09.2014 21:35
Für das logische "und" solltest du `&&` verwenden. Das einfache `&` macht ein bitweises "und" auf zwei Binärzahlen, was möglicherweise in manchen Fällen zu seltsamen Ergebnissen führen kann. Außerdem wird bei #strict 2 die rechte Seite von `&&` nicht ausgeführt, wenn die linke schon `false` ergibt. Das spart etwa in deinem Beispiel einen Funktionsaufruf.
Parent - By Serpens66 (More than 200 posts.) Date 17.09.2014 21:59
danke, hab ich gemacht =)
Parent - - By Serpens66 (More than 200 posts.) Date 17.09.2014 23:44 Edited 17.09.2014 23:48
oh man.. dieses Licht aus dem Hazardpack ... ist sooooo nervig :D ich frage mich echt, warum man das nicht anders gelöst hat bzw. warum man es nicht anders lösen kann :D

Ich meine es wird sowohl als Gebäude und Fahrzeug gewertet, was ja in meinen Threads hier schon für Probleme gesorgt hat. und nun sehe ich, da ich das Licht bei dem Plutonium hinzugefügt habe, dass es auch als einsammelbares Objekt gilt -.- 
Zumindest beim Hazardclonk, welcher mehrere Dinge tragen kann, macht sich das bemerkbar. Nachdem man Plutonium eingesammelt hat, rückt das Licht an erste stelle in seiner "tasche". Man kann es zwar werfen, aber weil es an das Plutonium gebunden ist, wird es aus der Welt entfernt und kehrt zurück in die Tasche :D   Um das Plutonium dann loszuwerden, muss man die Items durchschalten, sodass es an erster Stelle steht.

Das Hazardpack ist ja eig recht "berühmt" und auch zigfach überarbeitet. Wisst ihr warum das Licht all diese nervigen Eigenschaften hat/haben muss?

edit:
oder liegt das eher an meiner Funktion? was müsste ich da ändern? :

func Initialize()
{
  // rufe die Effektfunktion in diesem Objekt alle fünf Frames auf
  AddEffect("Radiate", this, 1, 10, this);
  TurnLightOn();
}
private func TurnLightOn()
{
  var iColor;
  iColor = RGBa(150,235,10,60);
  mlight = AddLight(1000, iColor, this());
  return(1);
}

private func TurnLightOff()
{
  if (mlight) RemoveObject(mlight);
  return(1);
}


Hm.. mir kommt gerade der Gedanke, dass man einfach den "TurnLightOff" befehl verwenden könnte, wenn das Objekt eingesammelt wird.
Wie lautet die Funktion dafür, die beim einsammeln aufgerufen wird? (beim fertigstellung eines Ojekts wird ja z.b die Funktion "Completion" aufgerufen. Es gibt da doch bestimmt eine Funktion fürs einsammeln, oder?)
Parent - - By Pyrit (More than 200 posts.) Date 18.09.2014 18:21
Schreib mal ins script von dem Objekt das eingesammelt wird^^:

func Entrance(object container)
{
    Message("Hui, ein %s hat mich eingesammelt! :D", container->GetName());
}
Parent - - By Serpens66 (More than 200 posts.) Date 18.09.2014 20:23 Edited 18.09.2014 20:35
dann kommt die Fehlermeldung:
ERROR: call to "Message" parameter 2: got "string", but expected "object"!
by: Entrance(Ringo #323) (obj Plutonium #41)

Edit:
aber wenn ich in die Funktion "TurnLightOff();"  schreibe, dann funktioniert das und das Licht geht aus und nervt nicht im inventar des Clonks =)
Jetzt muss es nur noch wieder angehen, wenn es wieder frei rumliegt... wie mache ich das?
Parent - - By Zapper (More than 500 posts.) Date 18.09.2014 20:57

>dann kommt die Fehlermeldung:


Das liegt daran, weil Pyrit zu viel OpenClonk codet. Da macht man nämlich obj->Message("Hi", ...) statt Message("Hi", obj, ...).

>Jetzt muss es nur noch wieder angehen, wenn es wieder frei rumliegt... wie mache ich das?


Der Counterpart zu Entrance ist Ejection

Siehe auch hier für viele andere interessante Callbacks: (Runterscrollen zur Tabelle)
http://www.clonk.de/docs/de/sdk/definition/script.html
Parent - By Serpens66 (More than 200 posts.) Date 18.09.2014 21:51 Edited 18.09.2014 22:02
vielen dank =)
hab mir den Link gleich eingespeichert :)

Openclonk schaue ich mir vllt irgendwann auch nochmal an.. aber der erste Eindruck war, dass das kein Clonk mehr ist.. da kann ich jedes andere x beliebige 3rd person shooter spiel spielen. Ist aber nur der erste eindruck, vllt trügt das ja ^^

Edit
achso, muss ich da auch "object container" in klammern schreiben? Wofür ist das in Pyrits funtktion gut?
Parent - - By Serpens66 (More than 200 posts.) Date 18.09.2014 22:25
hm.. Ejection funktioniert irgendwie nicht...

func Entrance(object pContainer)
{
    TurnLightOff();
}

func Ejection(object pObj)
{
TurnLightOn();
}

(habs auch schon ohne die Wörter in Kalmmern probiert, Entrance klappt, aber Ejection nicht. Es kommt aber auch keine Fehlermeldung. Das Licht geht nur nicht wieder an =/
Parent - - By Zapper (More than 500 posts.) Date 18.09.2014 23:16
Ah, mein Fehler. Du willst Departure und nicht Ejection.
Letzteres wird aufgerufen wenn ein anderes Objekt dieses Objekt verlässt. ZB. kriegt ein Gebäude bei Ejection mit wenn ein Clonk aus dem Gebäude rausgeht
Parent - By Serpens66 (More than 200 posts.) Date 18.09.2014 23:49
thanks =)
Parent - - By Luchs (More than 1000 posts.) Date 18.09.2014 21:35
Offensichtlich kam einfach nie jemand auf die Idee, einem einsammelbaren Objekt ein Licht zu geben. Hazard ist eben primär ein abgeschlossenes Objektpaket - da macht man sich nicht so viele Sorgen über seltsames Verhalten in Verbindung mit anderen Objekten.

Das Einsammelverhalten liegt im Übrigen an der `ATTACH`-Prozedur, da kann Hazard nicht so viel dafür. Am Besten, du schaltest einfach das Licht ab, wenn das Plutonium eingesammelt wird.
Parent - By Serpens66 (More than 200 posts.) Date 18.09.2014 21:54
ja da hast du recht ;)
Finde es ein wenig schade, dass die ganzen Pakete nicht kompatibel sind und wenn man alle pakete aufeinmal aktiviert, es einfach jahre dauert, bis es fertig geladen ist (und dazu dann tausend fehler) :D   das ist der Grund, weshalb ich mir ein eigenes Pack zusammenstelle. Ich nehme aus vorhandenen Packs das, was ich am besten finde, bzw. gerne kombinieren würde und versuche die Inkombatibilität zu beseitigen.

und ja ,das mit dem  ein-und ausschalten mache ich jetzt auch so =)
Parent - - By Pyrit (More than 200 posts.) Date 16.09.2014 22:35
Wenn nur die tragbaren Objekte Schaden verursachen sollen, versuch das von Zapper. :)

Wenn zusätzlich das Material selbst (also das Zeug, was man minen kann) Schaden verursachen soll, dann würde ich dem Clonk einen Effect geben, der kuckt, wie viele Pixel von dem Material im Umkreis sind, und entsprechend Schaden verursacht.
Parent - By Serpens66 (More than 200 posts.) Date 16.09.2014 22:45
danke für den Tipp =)
vllt komme ich darauf später nochmal zurück. Vorerst soll Plutonium aber nur als Brocken im Reaktor entstehen und nicht abbaubar sein.
Up Topic Deutsch / Hilfestellung / [Gelöst] Gegenstand radioaktiv machen

Powered by mwForum 2.29.7 © 1999-2015 Markus Wichitill